pascal-process: A new library for running processes and redirecting their output.

[pyscripter 778]

There are many components/libraries available for running processes and capturing their output.  But, I got frustrated with their design and functionality, mostly for the following reasons:

• Fixation with and premature conversion to strings. Processes produce and consume bytes.
• Blocking reading of process output, resulting to inefficiencies (tight loops with Sleep, or separate threads for reading the output or providing input to the process)
• Incomplete features and/or over-bloated

 

So, I have made my own pascal-process single unit library.

 

Main features:

• Asynchronous reading of process output
• Separate stdout and stderr reading which can optionally be merged
• Ability to consume output as it is produced or else let it accumulate and read the final result
• Ability to provide input to the running process before or while the process is running.
• Ability to terminate the running process.
• Synchronous and asynchronous execution of processes.
• Interfaced-based facilitating memory management.
• MIT licence

 

Usage:

You do not need to install the library. Just download or clone the repo and add the source subdirectory to the Library path.  Then add PascalProcess to your uses clause.

 

If you just want to get the output of a process you can use the class functions of TPProcess.

 

  TPProcess = class(TInterfacedObject, IPProcess)
    class function Execute(const ACommandLine: string;
      const ACurrentDir: string = ''): TBytes; overload;
    class procedure Execute(const ACommandLine: string;
      const ACurrentDir: string; out Output, ErrOutput: TBytes) overload;
  end;

This is an example:

var
  Output: TBytes;
begin
  Output := TPProcess.Execute('cmd /c echo Hi');
  Writeln(TEncoding.ANSI.GetString(Output));
end;

For more demanding cases you can use the IPProcess interface.

 

Example:

type
  TUtils = class
    class procedure OnRead(Sender: TObject; const Bytes: TBytes);
  end;

class procedure TUtils.OnRead(Sender: TObject; const Bytes: TBytes);
begin
  Writeln(TEncoding.ANSI.GetString(Bytes));
end;

procedure Test2;
// Processes ouput as it gets produced
// The main thread terminates the process
var
  Process: IPProcess;
begin
  Process := TPProcess.Create('cmd /c dir c:\ /s');
  Process.OnRead := TUtils.OnRead;
  WriteLn('Press Enter to start the process. Press Enter again to terminate');
  ReadLn;
  Process.Execute;
  ReadLn;
  Process.Terminate;
end;

See here the definition of IPProcess.

 

Limitations:

Currently the library is Windows only.  The intention is to support other platforms (help wanted).

Edited 3 hours ago by pyscripter